함수설명

바이너리웨이브(BinaryWave) 지표함수

작성방법

BW(단순이평기간, PROC기간, FastK기간, SlowK기간)

매개변수 설명

• "단순이평기간": Numeric, 최근 N개봉 기간값을 입력
• "PROC기간": Numeric, 최근 N개봉 기간값을 입력
• "FastK기간": Numeric, 최근 N개봉 기간값을 입력
• "SlowK기간": Numeric, 평활계수를 계산할 기간을 입력

<aside> 📘 계산

바이너리 웨이브는 MACD, 지수이동평균, ROC, 스톡캐스틱 총 4개의 지표를 이용하여 만든 지표입니다. 각 지표의 상태에 따라 값을 -1, 0, 1 값만 가지도록 하여 바이너리 웨이브값이 -4에서 4까지만 표현되도록 한것입니다.

A = macd가 macdSignal 보다 크면 1, 아니면 –1 B = 종가가 n일 이동평균보다 크면 1, 아니면 –1 C = ROC가 0이상이면 1, 아니면 –1 D = 스토케스틱이 50이상이면 1, 아니면 –1 BW = A+B+C+D

</aside>

활용예시

//인라인함수(수식안에서 만들어 사용하는 함수)
Function Infx_BW Numeric 
{
	Input 	: maPeriod(Numeric), ROCPeriod(Numeric), stoPeriod1(Numeric), stoPeriod2(Numeric);
	Var 	: value(0), value_EMA12(0), value_EMA26(0), value_Lowest(0);

	value_EMA12 = ema(C, 12);
	value_EMA26 = ema(C, 26);

	If value_EMA12 - value_EMA26 > ema(value_EMA12 - value_EMA26, 9) Then  
		value = 1; 
	Else  
		value = -1;

	If C > ma(C, maPeriod) Then  
		value = value + 1; 
	Else 
		value = value - 1;

	If (C - C[ROCPeriod]) / C[ROCPeriod] * 100 > 0 Then  
		value = value + 1; 
	Else 
		value = value - 1;

	value_Lowest = lowest(L, stoPeriod1);

	If  ema((C - value_Lowest) / (highest(H, stoPeriod1) - value_Lowest) * 100, stoPeriod2) > 50 Then  
		value = value + 1; 
	Else  
		value = value - 1;

	Infx_BW = value;
}
EndFunction

Input : maperiod(20), RocPeriod(12), stoPeriod1(5), stoPeriod2(3);
var : BinaryWave(0);

BinaryWave = Infx_BW(maperiod, RocPeriod, stoPeriod1, stoPeriod2);

Plot1(BinaryWave);
PlotBaseLine1(0, "기준선0");

<aside> 💡 뒤로가기는 좌측상단의 목차 버튼을 눌러주세요.

</aside>