함수설명

새로운 추세선 개체를 생성합니다. TL_New는 항상 추세선이 기본종목 위에 생성됩니다.

추세선이 생성되면 미리 지정한 양식에 따라 자동으로 식별번호가 부여됩니다. 10001부터 N번까지 번호가 부여되므로 추세선의 식별번호를 사용하기 위해서는 반드시 숫자형 변수에 할당하고 그 변수를 사용해야 합니다.

작성방법

TL_New(시작점날짜, 시작점시간, 시작점가격, 끝점날짜, 끝점시간, 끝점가격)

매개변수 설명

활용예시

Untitled

input : ChangeMethod(1); //1:변화율, 2: 포인트, 3: 틱수, 4: n봉 최고가/최저가 갱신
input : Change(10);      //ChangeMethod에 따라 변화율, 포인트, 틱수, n봉이 됨
input : UseClose(0);     //0이면 고가/저가 사용, 1이면 종가
Array : HD[10](0),HT[10](0),HV[10](0); //고점 날짜, 시간, 가격 저장할 배열
Array : LD[10](0),LT[10](0),LV[10](0); //저점 날짜, 시간, 가격 저장할 배열
var : cnt(0),Hprice(0),Lprice(0);
var : UpTrend(false),DownTrend(False),Trend(0);
var : ZigZagTL(0),HTL(0),LTL(0);

HPrice = IFf(UseClose == 1 ,C,H);
LPrice = IFf(UseClose == 1 ,C,L);

if Index == 0 Then
{
		//초기 최고값
		HD[0] = sDate;
		HT[0] = sTime;
		HV[0] = HPrice;
		//초기 최저값
		LD[0] = sDate;
		LT[0] = sTime;
		LV[0] = LPrice;
}
Else
{
		//ChangeMethod에 따른 추세전환 조건
		if ChangeMethod == 1 Then
		{
				UpTrend   = HPrice >= LV[0]*(1+Change/100);
				DownTrend = LPrice <= HV[0]*(1-Change/100);
		}
		else if ChangeMethod == 2 Then
		{
				UpTrend   = HPrice >= LV[0]+Change;
				DownTrend = LPrice <= HV[0]-Change;
		}
		else if ChangeMethod == 3 Then
		{
				UpTrend   = HPrice >= LV[0]+Change*PriceScale;
				DownTrend = LPrice <= HV[0]-Change*PriceScale;
		}
		Else
		{
				UpTrend   = HPrice >= Highest(HPrice,Change)[1];
				DownTrend = LPrice <= Lowest(LPrice,Change)[1];
		}

		//상승추세 전환
		if trend <= 0 and UpTrend == true Then
		{
				//추세구분 1
				trend = 1;
		
				//과거 고점의 날짜, 시간, 값을 다음 배열방으로 이동
				For cnt = 9 DownTo 1
				{
						HD[cnt] = HD[cnt-1];
						HT[cnt] = HT[cnt-1];
						HV[cnt] = HV[cnt-1];
				}
				//0번방에 날짜, 시간, 가격 저장
				HD[0] = sDate;
				HT[0] = sTime;
				HV[0] = HPrice;
				//직전 저점에서 현재 고점까지 연결선 출력
				ZigZagTL = TL_New(LD[0],LT[0],LV[0],HD[0],HT[0],HV[0]);
				//색상은 Red
				TL_SetColor(ZigZagTL,Red);
				//추세선 굵기는 1
				TL_SetSize(ZigZagTL,1);

				//상승전환되면 전저점과 최근저점을 연결하는 추세선 출력
				if LV[1] > 0 Then
				{
						//이전 저점 연결 추세선은 삭제
						TL_Delete(LTL);
						//새로 출력
						LTL = TL_New(LD[1],LT[1],LV[1],LD[0],LT[0],LV[0]);
						//색상은 Green
						TL_SetColor(LTL,Green);
						//추세선 굵기는 0
						TL_SetSize(LTL,0);
						//추세선 모양은 점선
						TL_SetStyle(LTL,3);
						//왼쪽으로 확장
						TL_SetExtLeft(LTL,true);
						//오른쪽으로 확장
						TL_SetExtRight(LTL,true);
				}
		
		} 
		Else if trend >= 0 and DownTrend Then//하락추세 전환
		{
				//추세구분은 -1
				trend = -1;
				
				//과거 저점의 날짜, 시간, 값을 다음 배열방으로 이동
				For cnt = 9 DownTo 1
				{
						LD[cnt] = LD[cnt-1];
						LT[cnt] = LT[cnt-1];
						LV[cnt] = LV[cnt-1];
				}
				
				//0번방에 날짜, 시간, 가격 저장
				LD[0] = sDate;
				LT[0] = sTime;
				LV[0] = LPrice;
		
				//직전 고점에서 현재 저점까지 연결선 출력
				ZigZagTL = TL_New(HD[0],HT[0],HV[0],LD[0],LT[0],LV[0]);
				//색상은 Blue
				TL_SetColor(ZigZagTL,Blue);
				//굴긱는 1
				TL_SetSize(ZigZagTL,1);

				//하락전환되면 전고점과 최근고점을 연결하는 추세선 출력
				if HV[1] > 0 Then
				{
						//이전 고점연결 추세선은 삭제
						TL_Delete(HTL);
						//새로 출력
						HTL = TL_New(HD[1],HT[1],HV[1],HD[0],HT[0],HV[0]);
						//색상은 Orange
						TL_SetColor(HTL,Orange);
						//추세선 굵기는 0
						TL_SetSize(HTL,0);
						//추세선 모양은 점선
						TL_SetStyle(HTL,3);
						//왼쪽으로 확장
						TL_SetExtLeft(HTL,true);
						//오른쪽으로 확장
						TL_SetExtRight(HTL,true);
				}
		}
		Else
		{
				//상승구간
				if trend == 1 Then
				{
						//고점이 갱신되면
						if HPrice > HV[0] Then
						{
								//갱신된 봉의 날짜/시간/가격으로 변경
								HD[0] = sDate;
								HT[0] = sTime;
								HV[0] = HPrice;
								//지그재그 추세선의 끝점을 현재봉으로 이동
								TL_SetEnd(ZigZagTL,HD[0],HT[0],HV[0]);
						}
				}
				//하락구간
				if trend == -1 Then
				{
						//저점이 갱신되면
						if LPrice < LV[0] Then
						{
								//갱신된 봉의 날짜/시간/가격으로 변경
								LD[0] = sDate;
								LT[0] = sTime;
								LV[0] = LPrice;
								//지그재그 추세선의 끝점을 현재봉으로 이동
								TL_SetEnd(ZigZagTL,LD[0],LT[0],LV[0]);
						}
				}
		}
}

<aside> 💡 뒤로가기는 좌측상단의 목차 버튼을 눌러주세요.

</aside>