함수설명

새로운 텍스트 개체를 생성합니다. Text_New_Self는 수식이 적용된 영역에 텍스트가 생성됩니다..

텍스트가 생성되면 미리 지정한 양식에 따라 자동으로 식별번호가 부여됩니다. 10001부터 N번까지 번호가 부여되므로 박스의 식별번호를 사용하기 위해서는 반드시 숫자형 변수에 할당하고 그 변수를 사용해야 합니다.

작성방법

Text_New_self(날짜, 시간, 가격, 문자열)

매개변수 설명

• "날짜": Numeric, 텍스트를 표시할 봉의 날짜, YYYYMMDD 형식으로 입력
• "시간": Numeric, 텍스트를 표시할 봉의 시간, HHMMSS 형식으로 입력
• "가격": Numeric, 텍스트를 표시할 봉의 가격
• "문자열": String, 표시할 내용, 숫자는 NumToStr 함수를 이용 스트링으로 변환해 지정

활용예시

input : sto1(10),sto2(5),sto3(5);
var : stok(0),stod(0),Text(0);
var : HV(0),HD(0),HT(0),LV(0),LD(0),LT(0);

stok = StochasticsK(sto1,sto2);       //스토케스틱 slowk
stod = StochasticsD(sto1,sto2,sto3);  //스토케스틱 slowd
		
//지표출력
plot1(stok,"slowk");
plot2(stod,"slowd");
PlotBaseLine1(20,"20",Black);
PlotBaseLine2(80,"80",Black);

//K-D 골드발생
if CrossUp(stok,stod) Then
{
		//골그구간 stok 최고가,날짜,시간 저장
		HV = stok;
		HD = sDate;
		HT = sTime;
		
		//텍스트 출력
		Text = Text_New_Self(HD,HT,HV,NumToStr(HV,2));
		//텍스트 색상은 Red
		Text_SetColor(Text,Red);
		//텍스트 크기는 12
		Text_SetSize(Text,12);
		//텍스트 폰트는 굴림
		Text_SetFont(Text,"굴림");
		//텍스트는 좌우정렬은 중앙, 상하정렬은 상
		Text_SetStyle(Text,2,1);
		
}
//K-D 골드발생
Else if CrossDown(stok,stod) Then
{
		//데드구간 stok 최저가, 날짜, 시간 저장
		LV = stok;
		LD = sDate;
		LT = sTime;
		//타원출력
		Text = Text_New_Self(LD,LT,LV,NumToStr(LV,2));
		//텍스트 색상은 Blue
		Text_SetColor(Text,Blue);
		//텍스트 크기는 12
		Text_SetSize(Text,12);
		//텍스트 폰트는 맑음 고딕
		Text_SetFont(Text,"맑은 고딕");
		//텍스트는 좌우정렬은 중앙, 상하정렬은 하
		Text_SetStyle(Text,2,0);
}
else 
{
		//골드 구간이면
		if stok > stod Then	
		{
				//stok최고가 갱신
				if stok > HV Then
				{
						HV = Stok;
						HD = sDate;
						HT = sTime;

					
						//텍스트의 위치를  새로움 고점봉으로 이동
						Text_SetLocation(Text,HD,HT,HV);
						//텍스트의 표시값을 새로운 고점값으로 변경
						Text_SetString(Text,NumToStr(HV,2));
				}
		}
		//데드구간이면
		if stok < stod Then	
		{
				//stok최저가 갱신
				if stok < LV Then
				{
						LV = Stok;
						LD = sDate;
						LT = sTime;

					
						//텍스트의 위치를  새로움 고점봉으로 이동
						Text_SetLocation(Text,LD,LT,LV);
						//텍스트의 표시값을 새로운 고점값으로 변경
						Text_SetString(Text,NumToStr(LV,2));
				}
		}
		
}

<aside> 💡 뒤로가기는 좌측상단의 목차 버튼을 눌러주세요.

</aside>