함수설명

지정한 텍스트의 표시내용을 변경합니다.

작성방법

Text_SetString(텍스트아이디, 표시내용)

매개변수 설명

• "텍스트아이디": Numeric, 표시내용을 변경할 텍스트의 식별번호
• "표시내용": String, 변경할 내용, 숫자는 NumToStr 함수를 이용 스트링으로 변환해 지정

활용예시

input : ChangeMethod(1); //1:변화율, 2: 포인트, 3: 틱수, 4: n봉 최고가/최저가 갱신
input : Change(10);      //ChangeMethod에 따라 변화율, 포인트, 틱수, n봉이 됨
input : UseClose(0);     //0이면 고가/저가 사용, 1이면 종가
Array : HD[10](0),HT[10](0),HV[10](0); //고점 날짜, 시간, 가격 저장할 배열
Array : LD[10](0),LT[10](0),LV[10](0); //저점 날짜, 시간, 가격 저장할 배열
var : cnt(0),Hprice(0),Lprice(0);
var : UpTrend(false),DownTrend(False),Trend(0);
var : ZigZagTL(0),Text(0);

HPrice = IFf(UseClose == 1 ,C,H);
LPrice = IFf(UseClose == 1 ,C,L);

if Index == 0 Then
{
		//초기 최고값
		HD[0] = sDate;
		HT[0] = sTime;
		HV[0] = HPrice;
		//초기 최저값
		LD[0] = sDate;
		LT[0] = sTime;
		LV[0] = LPrice;
}
Else
{
		//ChangeMethod에 따른 추세전환 조건
		if ChangeMethod == 1 Then
		{
				UpTrend   = HPrice >= LV[0]*(1+Change/100);
				DownTrend = LPrice <= HV[0]*(1-Change/100);
		}
		else if ChangeMethod == 2 Then
		{
				UpTrend   = HPrice >= LV[0]+Change;
				DownTrend = LPrice <= HV[0]-Change;
		}
		else if ChangeMethod == 3 Then
		{
				UpTrend   = HPrice >= LV[0]+Change*PriceScale;
				DownTrend = LPrice <= HV[0]-Change*PriceScale;
		}
		Else
		{
				UpTrend   = HPrice >= Highest(HPrice,Change)[1];
				DownTrend = LPrice <= Lowest(LPrice,Change)[1];
		}

		//상승추세 전환
		if trend <= 0 and UpTrend == true Then
		{
				//추세구분 1
				trend = 1;
		
				//과거 고점의 날짜, 시간, 값을 다음 배열방으로 이동
				For cnt = 9 DownTo 1
				{
						HD[cnt] = HD[cnt-1];
						HT[cnt] = HT[cnt-1];
						HV[cnt] = HV[cnt-1];
				}
				//0번방에 날짜, 시간, 가격 저장
				HD[0] = sDate;
				HT[0] = sTime;
				HV[0] = HPrice;

				//직전저점이 있으면
				if LV[0] > 0 Then
				{
						//직전 저점에서 현재 고점까지 연결선 출력
						ZigZagTL = TL_New(LD[0],LT[0],LV[0],HD[0],HT[0],HV[0]);
						//색상은 Red
						TL_SetColor(ZigZagTL,Red);
						//추세선 굵기는 1
						TL_SetSize(ZigZagTL,1);
	
						//현재 고점 위치에 고점값을 텍스트로 출력
						Text = Text_New(HD[0],HT[0],HV[0],NumToStr(HV[0],2));
						//텍스트 색상은 Red
						Text_SetColor(Text,Red);
						//텍스트 크기는 12
						Text_SetSize(Text,12);
						//텍스트 폰트는 굴림
						Text_SetFont(Text,"굴림");
						//텍스트를 굵게 설정
						Text_SetBold(Text,1);
						//텍스트는 좌우정렬은 중앙, 상하정렬은 상
						Text_SetStyle(Text,2,1);
				}	
		} 
		Else if trend >= 0 and DownTrend Then//하락추세 전환
		{
				//추세구분은 -1
				trend = -1;
				
				//과거 저점의 날짜, 시간, 값을 다음 배열방으로 이동
				For cnt = 9 DownTo 1
				{
						LD[cnt] = LD[cnt-1];
						LT[cnt] = LT[cnt-1];
						LV[cnt] = LV[cnt-1];
				}
				
				//0번방에 날짜, 시간, 가격 저장
				LD[0] = sDate;
				LT[0] = sTime;
				LV[0] = LPrice;
				
				if HV[0] > 0 Then
				{
						//직전 고점에서 현재 저점까지 연결선 출력
						ZigZagTL = TL_New(HD[0],HT[0],HV[0],LD[0],LT[0],LV[0]);
						//색상은 Blue
						TL_SetColor(ZigZagTL,Blue);
						//굵기는 1
						TL_SetSize(ZigZagTL,1);
	
						//현재 저점 위치에 저점값을 텍스트로 출력
						Text = Text_New(LD[0],LT[0],LV[0],NumToStr(LV[0],2));
						//텍스트 색상은 Blue
						Text_SetColor(Text,Blue);
						//텍스트 크기는 12
						Text_SetSize(Text,12);
						//텍스트 폰트는 맑음 고딕
						Text_SetFont(Text,"맑은 고딕");
						//텍스트를 굵게 설정
						Text_SetBold(Text,1);
						//텍스트는 좌우정렬은 중앙, 상하정렬은 하
						Text_SetStyle(Text,2,0);
				}
		}
		Else
		{
				//상승구간
				if trend == 1 Then
				{
						//고점이 갱신되면
						if HPrice > HV[0] Then
						{
								//갱신된 봉의 날짜/시간/가격으로 변경
								HD[0] = sDate;
								HT[0] = sTime;
								HV[0] = HPrice;
								
								//지그재그 추세선의 끝점을 현재봉으로 이동
								TL_SetEnd(ZigZagTL,HD[0],HT[0],HV[0]);

								//텍스트의 위치를  새로움 고점봉으로 이동
								Text_SetLocation(Text,HD[0],HT[0],HV[0]);
								//텍스트의 표시값을 새로운 고점값으로 변경
								Text_SetString(Text,NumToStr(HV[0],2));
						}
				}
				//하락구간
				if trend == -1 Then
				{
						//저점이 갱신되면
						if LPrice < LV[0] Then
						{
								//갱신된 봉의 날짜/시간/가격으로 변경
								LD[0] = sDate;
								LT[0] = sTime;
								LV[0] = LPrice;
								
								//지그재그 추세선의 끝점을 현재봉으로 이동
								TL_SetEnd(ZigZagTL,LD[0],LT[0],LV[0]);
								
								//텍스트의 위치를  새로움 저점봉으로 이동
								Text_SetLocation(Text,LD[0],LT[0],LV[0]);
								//텍스트의 표시값을 새로운 고점값으로 변경
								Text_SetString(Text,NumToStr(LV[0],2));
						}
				}
		}
}

<aside> 💡 뒤로가기는 좌측상단의 목차 버튼을 눌러주세요.

</aside>